Error handling in Software AG’s Natural can be done in a way that resembles Exception handling in object-oriented languages like Java.
Instead of throwing an Exception, you raise an error simply by assigning a value to the system variable *ERROR-NR. As soon as a statement like the following is executed, the current program flow is interrupted and the nearest ON ERROR block is executed.
*ERROR-NR := 1234
In fact, we use exactly this feature for raising assertion errors in NatUnit.
You can handle a Natural error in an ON ERROR block anywhere inside your code. Just like an Exception travels up through the call stack to get caught in the nearest
try-catch block, a Natural error is handled in the nearest
ON ERROR block.
Here’s an example of an
ON ERROR block that exits the current module and marks the error as handled:
ON ERROR /* do something about it */ ESCAPE MODULE END-ERROR
catch (SpecificException e)
You can only define a single
ON ERROR block in each Natural module. So if you need to handle specific errors in a different way, you need to have some kind of distinction logic like this:
ON ERROR IF *ERROR-NR EQ 1234 /* do something about it */ ESCAPE MODULE END-IF END-ERROR
Or if you need to distinguish between multiple errors:
ON ERROR DECIDE ON FIRST VALUE OF *ERROR-NR VALUE 1234 /* do something about it */ ESCAPE MODULE VALUE 1235 /* do something about it */ ESCAPE MODULE NONE IGNORE END-DECIDE END-ERROR
If you can’t handle the error in an
ON ERROR block, but you want to log it or do something else with it before letting the next
ON ERROR block handle it, you don’t need to do anything at all, because that’s the default behaviour.
However, if you exit the
ON ERROR block with any statement from the following list, the error is marked as handled and the normal control flow (in the calling module of the module containing the
ON ERROR block) is continued. So be sure not to exit the block with any of these statements.
Exiting from an ON ERROR Block:
ON ERRORblock may be exited by using a
ESCAPE MODULEstatement. If the block is not exited using one of these statements, standard error message processing is performed and program execution is terminated.
Here’s an example of such a “re-throw”:
ON ERROR IF *ERROR-NR EQ 1234 /* log the error */ /* DON'T exit with `FETCH`, `STOP`, `TERMINATE`, `RETRY`, `ESCAPE ROUTINE` or `ESCAPE MODULE` */ END-IF END-ERROR
Checking which error occurred
Even if you “handle” the Natural error in an
ON ERROR block, e.g. by using
ESCAPE MODULE, the system variable
*ERROR-NR isn’t reset to
0. You need to do that yourself, if you need to. If you don’t, the variable can be used in the calling module to check whether an error (that was handled) occured. By the way, the system variable
*ERROR-LINE contains the line number of the statement that raised the error.
CALLNAT 'CALLEE' IF *ERROR-NR NE 0 WRITE 'Error' *ERROR-NR 'occurred in line' *ERROR-LINE 'while calling CALLEE' /* prints: "Error 1234 occurred while calling CALLEE" */ END-IF END
*ERROR-NR := 1234 ON ERROR ESCAPE MODULE END-ERROR END
If you don’t want any caller to know that an error occurred, simply reset
ON ERROR RESET *ERROR-NR ESCAPE MODULE END-ERROR
Global error handler (like a try-catch in main())
You can define a global error handler by setting the system variable
*ERROR-TA to the name of a Natural module. In case of an error, Natural automatically calls this module (which has to be a program) and puts information about the error on the stack. The system variables
*ERROR-LINE will be reset at this point, so the error handler has to read the information from the stack with
*ERROR-TA := 'HANDLER' CALLNAT 'CALLEE' END
*ERROR-NR := 1234 END
DEFINE DATA LOCAL 1 #ERROR-NR (N5) 1 #LINE (N4) 1 #STATUS-CODE (A1) 1 #PROGRAM (A8) 1 #LEVEL (N2) 1 #LEVELI4 (I4) 1 #POSITION-IN-LINE (N3) 1 #LENGTH-OF-ITEM (N3) END-DEFINE /* read error information from stack */ INPUT #ERROR-NR #LINE #STATUS-CODE #PROGRAM #LEVEL #LEVELI4 WRITE #ERROR-NR #LINE #STATUS-CODE #PROGRAM #LEVEL #LEVELI4 #STATUS-CODE WRITE *ERROR-NR *ERROR-LINE END
1234 10 O CALLEE 2 0 O 0 0
For more information about the error information on the stack take a look at the section Using an Error Transaction Program in the Natural documentation.
Getting more information about errors programmatically
If you need to find out more about the current error, e.g. in your
ON ERROR block, there are quite a few User Exits that deal with errors:
- USR0040N: Get type of last error
- USR1016N: Get error level for error in nested copycodes
- USR2001N: Get information on last error
- USR2006N: Get information from error message collector
- USR2007N: Get or set data for RPC default server
- USR2010N: Get error information on last database call
- USR2026N: Get TECH information
- USR2030N: Get dynamic error message parts from the last error
- USR3320N: Find user short error message (including steplibs search)
- USR4214N: Get program level information